Réception BLE Simple WINDEV Mobile & ESP32

#include <BLEDevice.h>
#include <BLEServer.h>
#include <BLEUtils.h>
#include <BLE2902.h>
 
//
// Les UUID sont unique pour vous, vous pouvez en générer pour chaque application
//
 
#define SERVICE_UART_UUID      "6E400001-B5A3-F393-E0A9-E50E24DCCA9E"
#define CHARACTERISTIC_UUID_RX "6E400002-B5A3-F393-E0A9-E50E24DCCA9E"
#define CHARACTERISTIC_UUID_TX "6E400003-B5A3-F393-E0A9-E50E24DCCA9E"
 
BLEServer* pServer = NULL;
BLECharacteristic* pTxCharacteristic = NULL;
BLECharacteristic* pRxCharacteristic = NULL;
 
bool estConnecte = false;
bool etaitConnecte = false;
 
 
class EtatServeur : public BLEServerCallbacks
{
	void onConnect(BLEServer* pServer)
	{
		estConnecte = true;
	}
 
	void onDisconnect(BLEServer* pServer)
	{
		estConnecte = false;
	}
};
 
class CharacteristicUART : public BLECharacteristicCallbacks
{
	void onWrite(BLECharacteristic* pCharacteristique)
	{
		std::string rxValue = pCharacteristique->getValue();
 
		if (rxValue.length() > 0)
		{
			Serial.println("*********");
			Serial.print("Received Value: ");
			for (int i = 0; i < rxValue.length(); i++)
				Serial.print(rxValue[i]);
			Serial.println();
			Serial.println("*********");
		}
	}
};
 
 
void setup() {
	Serial.begin(115200);
 
	// Create the BLE Device
	BLEDevice::init("TEST-UART");
 
	//BLEDevice::getAddress(); // pour récupere la MAC adresse de votre BLE
	pServer = BLEDevice::createServer();
	pServer->setCallbacks(new EtatServeur());
 
	BLEService* pServiceUART = pServer->createService(SERVICE_UART_UUID);
	pTxCharacteristic = pServiceUART->createCharacteristic(CHARACTERISTIC_UUID_TX, BLECharacteristic::PROPERTY_NOTIFY);
	// Create a BLE Descriptor : Client Characteristic Configuration (for indications/notifications)
	pTxCharacteristic->addDescriptor(new BLE2902());
	pRxCharacteristic = pServiceUART->createCharacteristic(CHARACTERISTIC_UUID_RX, BLECharacteristic::PROPERTY_WRITE);
	pRxCharacteristic->setCallbacks(new CharacteristicUART());
 
	pServiceUART->start();
 
	pServer->getAdvertising()->start();
	Serial.println("UART Over BLE start advertising");
 
	Serial.println("UART Over BLE wait connection");
}
 
void loop() {
	String newValue = "";
	bool fini = false;
 
	//Si connecté envoie en permanance newValue, mais il peux être envoyé qu'a chaque 
	// chaque modification de valeur, a vous de coder dans ce sens
	if (estConnecte)
	{
		// envoie 
		newValue = "TEXT ENVOYER";
 
		pTxCharacteristic->setValue(newValue.c_str());
		pTxCharacteristic->notify();
		delay(10); // bluetooth stack will go into congestion, if too many packets are sent
 
	}
 
	// déconnecté ?
	if (!estConnecte && etaitConnecte)
	{
		Serial.println("UART Over BLE deconnection");
		delay(500); // give the bluetooth stack the chance to get things ready      
		pServer->startAdvertising(); // restart advertising
		Serial.println("UART Over BLE restart advertising");
		etaitConnecte = estConnecte;
	}
 
	// connecté ?
	if (estConnecte && !etaitConnecte)
	{
		Serial.println("UART Over BLE connection");
		etaitConnecte = estConnecte;
 
	}
}

BTLEListePériphérique(detectUART)


	PROCÉDURE INTERNE detectUART(BLE est un btlePériphérique)
	crtq est une btleCaractéristique
		SI BLE.Nom = "TEST-UART"
			// On vérifie si on n'a pas déjà ajouté ce périphérique
			
			// On vérifie la connexion n'a pas déjà été effectuée
			SI BTLEEtatConnexion(BLE) <> btleEtatConnecté ALORS
				LIB_UART = ""
				
				// Lancement de la connexion
				SI BTLEConnecte(BLE) ALORS
					crtq = BTLERécupèreUneCaractéristique(BTLERécupèreUnService(BLE,"6E400001-B5A3-F393-E0A9-E50E24DCCA9E"),"6E400003-B5A3-F393-E0A9-E50E24DCCA9E")
					BTLECaractéristiqueChangementValeur(crtq,showUART)
					ToastAffiche("Connexion UART OK",toastLong)
					RENVOYER Faux
				FIN
			FIN
		FIN
	FIN
	
	PROCÉDURE INTERNE showUART(caractéristique est une btleCaractéristique <utile>, bufValeur est un Buffer)
	sBuf est une chaîne ANSI = bufValeur
	LIB_UART = sBuf
	FIN